Synapse. Работа с FTP-протоколом.

Сегодня рассмотрим работу с ещё одним сетевым протоколом с использованием библиотеки Synapse – File Transfer Protocol (FTP).

Давно уже собирался написать про него, но всё как-то было лень :) Сегодня решил всё-таки выкроить немного времени и разобраться с работой с FTP-протоколом в Synapse. Для начала я решил немного поиздеваться над FTP-шником своего блога и написать небольшую программку, реализующую основные операции: логин, чтение списка каталогов, загрузка на сервер, скачивание с сервера и т.д. Поэтому сегодня рассмотрим рабочий пример, а в конце поста я дам ссылку на страничку описания класса TFTPSend.

Как Вы уже поняли из введения к посту, работа с FTP в Synapse организуется через использование экземпляров класса TFTPSend, который находится в модуле ftpsend.pas. Поэтому можете запускать Delphi и смело подключать этот модуль в uses.

Вначале накидаем компоненты на форму. Я решил сделать главную форму приложения такой:

На форме расположены:

1. 4 Edit’а – для определения параметров подключения;
2. 2 кнопки TButton – для коннекта и дисконнекта (хотите – сделайте одну для обеих операций – это не суть)
3. 1 ListView для вывода содержимого текущей директории
4. 1 Memo для ведения лога работы – сюда будем записывать некоторые сообщения от сервера, чисто для наглядности и не более.

1. Коннектимся к серверу

Первое, что нам необходимо – это авторизоваться на сервере. Для этого определим переменную:

FTPClient: TFTPSend;

и в обработчике OnClick кнопки «Login» напишем следующий код:

  FTPClient:=TFTPSend.Create;
  FTPClient.TargetHost:=Edit1.Text;
  FTPClient.TargetPort:=Edit2.Text;
  FTPClient.UserName:=Edit3.Text;
  FTPClient.Password:=Edit4.Text;
  FTPClient.PassiveMode:=CheckBox1.Checked;
  if FTPClient.Login then
   begin
     Memo1.Lines.Add('Логин прошел успешно');
   end;

Здесь следует обратить внимание на то, что при определении параметров одключения использовались свойства родителя для TFTPSend, т.е. класса TSynaClient. Сам же TFTPSend содержит аналогичные свойства с префиксом «FW» — эти свойства определяются для работы с брендмауэром. Итак мы определили:

• TargetHost — хост FTP
• TargetPort — порт (по умолчанию — 21)
• UserName — имя пользователя
• Password — пароль доступа

и затем воспользовались методом Login для доступа к серверу. Если Login вернул True — значит коннект прошел успешно и можно продолжать работу (получать список каталогов, качать файлы и т.д.) Движемся далее.

Как узнать текущую директорию в которой мы находимся и перемещаться по директориям?

Для этого у TFTPSend имеется несколько методов:

GetCurrentDir – возвращает имя директории в которой мы находимся на данный момент.

function ChangeWorkingDir(const Directory: string): Boolean; virtual;

Меняет текущую директорию на директорию Directory и, в случае успеха, возвращает True.

function ChangeToParentDir: Boolean; virtual;

Изменяет текущу директория на деректорию, лежащую на один уровень вверх от текущей и, в случае успеха, возвращает True.

function ChangeToRootDir: Boolean; virtual;

Переходит в корневую директорию на сервере. Функция может не сработать (вернуть False), например, в случае, когда используется FTP на бесплатном хостинге — там доступ дается обычно не на корень а на отдельную директорию лежащую на хз каком уровне от Root’а.

Теперь можете дописать обработчик, например так, чтобы в лог выписывалась текущая директория на сервере.

Предположим, что коннект состоялся, мы знаем где находимся на сервере.

Как нам теперь получить список всех директорий и файлов в текущей нашей директории?

Для этого нам потребуется метод:

function List(Directory: string; NameList: Boolean): Boolean; virtual;

Загружает список всех директорий и файлов, находящихся в директории Directory. Если свойство Directory имеет нулевое значение (пустая строка), то загружается список из текущей директории. Параметр NameList указывает на то, что загружаться должны только названия директорий и файлов.

Все загруженные данные сохраняются в списке:

property FtpList: TFTPList read FFtpList;

Остается совершеннейшая малость – дописать обработчик с целью получения списка всех директорий и файлов, находящихся в текущей директории. Путь он (обработчик) будет у нас теперь таким:

procedure TForm2.Button1Click(Sender: TObject);
var i:integer;
begin
  FTPClient:=TFTPSend.Create;
  FTPClient.TargetHost:=Edit1.Text;
  FTPClient.TargetPort:=Edit2.Text;
  FTPClient.UserName:=Edit3.Text;
  FTPClient.Password:=Edit4.Text;
  FTPClient.PassiveMode:=CheckBox1.Checked;
  if FTPClient.Login then
   begin
     Memo1.Lines.Add('Логин прошел успешно');
     Memo1.Lines.Add('Текущая директория '+FTPClient.GetCurrentDir);
     ListView1.Clear;
     FTPClient.List(FTPClient.GetCurrentDir,false);
     for i := 0 to FTPClient.FtpList.Count-1 do
       begin
         with ListView1.Items.Add do
           begin
             Caption:=FTPClient.FtpList[i].FileName;
             if FTPClient.FtpList[i].Directory then
                SubItems.Add('директория')
             else
               SubItems.Add('файл');
             SubItems.Add(DateToStr(FTPClient.FtpList[i].FileTime))
 
           end;
       end;
   end;
   Memo1.Lines.Add(FTPClient.FullResult.Text);
end;

Запустим программу и проверим работу:

Остается только определиться как скачивать/закачивать файлы.

Для примера, предлагаю бросить на форму TOpenDialog, создать простой txt-файлик и покидать его туда-обратно.

Вначале сделаем загрузку файла НА сервер. В общем случае процедура загрузки файла на сервер может выглядеть следующим образом:

  if OpenDialog1.Execute then
    begin
      FTPClient.DataStream.LoadFromFile(OpenDialog1.FileName);//записали содержимое файла в поток
      FTPClient.StoreFile(ExtractFileName(OpenDialog1.FileName),false);//сохранили на сервер
      FTPClient.List(FTPClient.GetCurrentDir,false);//прочитали новое содержимое директории
      {перечисляем имена директорий и файлов}
    end;

Вначале, записываем всё содержимое файла в поток DataStream. Затем сохраняем содержимое потока на сервере, задав имя файла. После загрузки вновь получаем список файлов и диреторий на сервере и выводим их в ListBox. Остается только отметить, что в функции StoreFile второй параметр указывает — будет ли файл сразу же загружен на сервер или его загрузка будет отложена (при условии, что сервер поддерживает отложенные загрузки). Таким образом Вы можете практически без проблем организовывать в своих программах очереди згрузок. Ну и, наконец, обратная операция — получение файла с сервера. Вид процедуры может быть таким:

 FTPClient.RetrieveFile('Имя_файла_на_сервере',false);//прочитали файл в поток
 FTPClient.DataStream.SaveToFile('Имя_файла_на_диске');//сохранили из потока на диск

Вот пожалуй и основные навык работы с FTP в Synapse. Думаю, что смысл понятен, а остальное будем разбирать по ходу дела :) Пока можете почитать дополнительно: Что представляет из себя FTP

Книжная полка

	Автор: Андрей Шкрыль Название: Разработка клиент-серверных приложений в Delphi Описание: Рассмотрены практические вопросы по разработке клиент-серверных приложений в среде Delphi 7 и Delphi 2005 с использованием СУБД MS SQL Server 2000, InterBase и Firebird. Приведена информация о теории построения реляционных баз данных и языке SQL. Освещены вопросы эксплуатации и администрирования СУБД.
	Автор: Антон Григорьев Название: О чем не пишут в книгах по Delphi Описание: Рассмотрены малоосвещенные вопросы программирования в Delphi. Описаны методы интеграции VCL и API. Показаны внутренние механизмы VCL и приведены примеры вмешательства в эти механизмы. Рассмотрено использование сокетов в Delphi: различные режимы их работы, особенности для протоколов TCP и UDP и др.