Synapse. Отправка данных на сервер на примере imagevenue.com.

В большинстве случаев, при рассмотрении в блоге вопросов использования библиотеки Synapse, а именно при работе с THTTPSend я ограничивался тем, что рассказывал как получать какие-либо данные из Сети, например, текст страницы или, на крайний случай, правильно работать с веб-формами, когда надо было залогинится на сайте или отправить на сервер какой-нибудь текст. Но между тем, иногда может потребоваться и отправка более “весомых” данных, чем простой текст, например, загрузить картинку на фотохостинг.

В качестве примера рассмотрим работу с сайтом imagevenue.com.

Итак, повторение – мать учения. Начнем по-порядку — с анализа сайта.

Во-первых, ищем страничку с которой можно хостить свои картинки через простую вею-форму. Такая страничка имеется и её URL — http://imagevenue.com/host.php. Заходим на страничку и начинаем анализировать заголовки сервера. Как анализировать заголовки я рассказывал как минимум дважды – здесь и здесь. Я буду использовать в сниффер для FireFox – HTTP Live Headers.

выбираем какую-нибудь картинку у себя на компьютере, указываем содержимое картинки и отправляем файл на сервер:

После отправки внимательно изучаем заголовки сервера. Необходимо найти POST-запрос в котором отправляется картинка на сервер. На рисунке ниже представлен этот самый запрос, а также выделены заголовки, на которые необходимо обратить внимание:

Какие выводы можно сделать, судя по заголовкам:

1. Запрос необходимо отправлять на URL http://imagevenue.com/upload.php (см. путь в первой строке после “POST”)
2. В запросе множественное содержимое, т.е. тело запроса может состоять из нескольких частей, разделенных границей. Этот вывод мы делаем, исходя из данных во второй выделенной строке: multipart/form-data – указывает на множественное содержимое, всё, что содержится после “boundary=” – разделитель для частей тела запроса.
3. Каждая часть должна сдержать по два заголовка: первый заголовок Content-Disposition в котором можно указать название файла; второй заголовок – тип контента в данном случае хостинг принимает только jpeg, что несколько упрощает наше работу.

Теперь нам остается только правильно составить запрос в Delphi, используя THTTPSend. О том, как составляются подобные запросы я рассказывал здесь, но распишем метод ещё раз более детально. Итак, процедура отправки файла на сервер:

procedure TForm1.Button1Click(Sender: TObject);
Const
  CRLF = #$0d+#$0a;
var
  HTTP: THTTPSend;
  s: AnsiString;
  FS: TFileStream;
begin
  if OpenDialog1.Execute then
  begin
    try 
     HTTP := THTTPSend.Create;
     FS:=TFileStream.Create(OpenDialog1.FileName, fmOpenRead); 
      HTTP.MimeType := 'multipart/form-data; boundary=END_OF_PART';
    { Записываем Mime-тип и данные по файлу }
      s := '--END_OF_PART' + CRLF +
        'Content-Disposition: form-data; name="userfile[]"; filename="FileName.jpg"'
        + CRLF + 'Content-Type: image/jpeg' + CRLF + CRLF;
      HTTP.Document.Write(PAnsiChar(s)^, Length(s));
      FS.Position := 0;
      // записываем файл в тело документа
      HTTP.Document.CopyFrom(FS, FS.Size);
    { завершаем тело запроса }
    s := CRLF + '--END_OF_PART--' + CRLF;
    HTTP.Document.Write(PAnsiChar(s)^, Length(s)); // завершили тело документа
    // Отправляем запрос
    if HTTP.HTTPMethod('POST', 'http://imagevenue.com/upload.php') then
    begin
      ShowMessage(HTTP.ResultString);
      mmo1.Lines.LoadFromStream(HTTP.Document);
    end;
    finally 
      FS.Free;
      HTTP.Free;
    end;      
  end;
end;

Разберем подробно, что мы сделали. Во-первых, создаем объект HTTP:THTTPSend и загружаем выбранный файл в файловый поток FS:TFileStream.

Определяем тип данных в точности как и в ранее полученных заголовках:

HTTP.MimeType := 'multipart/form-data; boundary=END_OF_PART';

Обратите внимание на то как указан разделитель — «END_OF_PART«. Я написал так, чтобы подчеркнуть назначение строки, записываемой в boundary, в рабочем приложении вы обязаны предусмотреть, чтобы последовательность байтов разделителя никогда не встречалась в файле. Для этого можно, например, воспользоваться генератором случайных чисел и плюс добавить к разделителю какую-нибудь строку типа «———ProgName——« — врядли полученная строка встретиться в файле. В общем — фантазируйте :)

Далее мы записываем в тело запроса следующие строки:

—END_OF_PART’ + CRLF — определяем начало новой части документа и переходим на новую строку

Content-Disposition: form-data; name=»userfile[]»; filename=»FileName.jpg» — заголовок. Здесь желательно указать правильное название файла (вместо FileName.jpg), а также обязательно должна присутствовать строка «form-data».

Подстрока name=»userfile[]»; в нашем случае определяет какой по счёту файл из формы отправляется — первый.

CRLF + ‘Content-Type: image/jpeg’ + CRLF + CRLF; — переходим на новую строку, определяем тип данных (картинка jpeg), пропускам одну строку.

После этого – пишем данные из файлового потока в тело документа:

  FS.Position := 0;
  HTTP.Document.CopyFrom(FS, FS.Size);

Завершаем часть документа, записав в тело запроса строку:

  s := CRLF + '--END_OF_PART--' + CRLF;
  HTTP.Document.Write(PAnsiChar(s)^, Length(s));

Только после этого мы отправляем запрос и анализируем результат. В нашем случае мы просто выводим сообщение м ответом сервера и выписываем полученный в ответе документ в Memo:

if HTTP.HTTPMethod('POST', 'http://imagevenue.com/upload.php') then
  begin
    ShowMessage(HTTP.ResultString);
    mmo1.Lines.LoadFromStream(HTTP.Document);
 end;

В случае успешно отправленного запроса в Memo попадет текст страницы, содержащий миниатюру нашей картинки, а также все HTML-коды для вставки картинки на страницы блогов, форумов и т.д.

Вот, собственно, вся “хитрость” отправки данных на сервер фотохостнга. Кстати, если для вас не принципиально получение HTML-кода ответной страницы, то в Synapse в том же модуле httpsend.pas есть замечательная функция HttpPostBinary, которую можно использовать для отправки бинарных данных на сервер методом POST, если запрос проходит успешно, то функция возвращает TRUE.

Вот и все :) Исходники не выкладываю, т.к. весь исходник – это процедура, представленная выше.

Книжная полка

	Автор: Андрей Шкрыль Название: Разработка клиент-серверных приложений в Delphi Описание: Рассмотрены практические вопросы по разработке клиент-серверных приложений в среде Delphi 7 и Delphi 2005 с использованием СУБД MS SQL Server 2000, InterBase и Firebird. Приведена информация о теории построения реляционных баз данных и языке SQL. Освещены вопросы эксплуатации и администрирования СУБД.
	Автор: Антон Григорьев Название: О чем не пишут в книгах по Delphi Описание: Рассмотрены малоосвещенные вопросы программирования в Delphi. Описаны методы интеграции VCL и API. Показаны внутренние механизмы VCL и приведены примеры вмешательства в эти механизмы. Рассмотрено использование сокетов в Delphi: различные режимы их работы, особенности для протоколов TCP и UDP и др.