Парсинг JSON в Delphi под Windows и MacOS.

Эта статья небольшое продолжение сразу трех статей: «Delphi XE2: Hello, Mac OS!» в которой рассмотрен простенький пример создания приложения а-ля «Hello, World!» под MacOS, «Работа с JSON в Delphi 2010 — XE2.» с информацией по классам для работы с JSON в Delphi и последней статьи, касающейся работы с Google API — «Использование JSON при работе с Google API.«. В общем, сегодня попытаемся распарсить под MacOS JSON-объект, содержащий информацию по контактам GMail и, в дополнение, посмотреть как туже самую операцию парсинга можно осуществить под Windows, используя не только «родные» классы Delphi XE2 для работы с JSON, но и такую замечательную библиотеку как SuperObject.

Прежде, чем рассмотрим основную тему статьи, я рассмотрю один момент, с которым, думаю, кто-то мог столкнуться при настройке соединения между Windows и MacOS, а именно — разного рода возникающие ошибки типа «SocketError #» и то, как этих ошибок можно избежать.

PAServer: ошибки «SocketError #»

В последнее время я практически не заглядывал в свою виртуалку с MacOS. А сегодня решил написать пост, запустил виртуальную машину и при попытке собрать проект под Mac получил сообщение «SocketError #10060» затем, при неизменных настройках, вдруг вылетела ошибка «SocketError #11004«. Пошел простым логическим путем: PAServer после последнего запуска никаким образом не трогал, настроек не менял, паролей не  устанавливал. Следовательно PAServer просто так взять и «упасть» не мог, тем более, выдавая ошибку сокета.  Значит произошла какая-то непонятная фигня с настройками сети. Вначале проверил настройку сети в виртуалке VMware. Настройки были и остались такими:

В виртуалке веб-браузер работает нормально — сайты открываются, файлы грузятся. Следовательно проблема заключается в настройках под Windows. Зашел в настройки Сети и увидел следующую картинку:

Где-то с месяц назад менял настройки Сети и видимо отключил это соединение за ненадобностью, а включить забыл. После того как адаптер виртуалки был включен заново PAServer как и раньше заработал без каких-либо проблем. Так что, если у вас при настройке PAServer’а возникают ошибки как у меня  «SocketError #10060«, «SocketError #11004» и т.д., то в первую очередь смотрите настройки сетевых соединений.

Теперь перейдем непосредственно к теме статьи — парсингу JSON в MacOS и Windows.

Для визуального представления JSON-объекта, который будет разобран ниже, я буду использовать Онлайн-вьювер JSON-объектов — отличный инструмент, когда необходимо быстро посмотреть как выглядит какой-либо JSON-объект. Например, объект, который будет разбираться в это статье, выглядит во вьювере вот так:

Сразу видно где какие объекты и массивы расположены в JSON и как до них добраться. Теперь перейдем непосредственно к парсингу.

Парсинг  JSON в Delphi под Windows

Итак, вид JSON-объекта, содержащего данные по контактам представлен на рисунке ниже. Для примера, попробуем прочитать title контакта. Судя по составу JSON-объекта от нас требуется:

1. Получить объект feed
2. В feed добраться до массива entry
3. Пройти по каждому элементу в entry и получить объект title
4. Получить из объекта title пару $t
5. Прочитать значение пары $t

Для реализации этого простенького алгоритма вначале воспользуемся «родной» библиотекой Delphi XE2, которая содержится в модуле Data.DBXJSON.pas. Ниже представлен один из возможных вариантов парсинга JSON с помощью DBXJSON:

procedure TForm3.Button3Click(Sender: TObject);
var
  JsonObject, GFeed, GContact, GTitle: TJSONObject;
  JsonStream: TStringStream;
  JsonArray: TJSONArray;
  i: integer;
  Pairs: TJSONPairEnumerator;
begin
  JsonStream := TStringStream.Create;
  try
    JsonStream.LoadFromFile(edFile.Text); //загружаем данные из вайла
    //создаем объект TJSONObject
    JsonObject := TJSONObject.ParseJSONValue(JsonStream.DataString) as TJSONObject;
    if Assigned(JsonObject) then
    begin
      //получаем перечислитель всех пар в объекте
      Pairs := JsonObject.GetEnumerator;
      try
        while Pairs.MoveNext do //проходим по парам в цикле
        begin
          //ищем пару feed
          if Pairs.Current.JsonString.Value = 'feed' then
          begin
            GFeed := Pairs.Current.JsonValue as TJSONObject;
            //получаем массив entry
            JsonArray := GFeed.Get('entry').JsonValue as TJSONArray;
            if Assigned(JsonArray) then
            begin
              //проходим по каждому элементу массива
              for i := 0 to JsonArray.Size - 1 do
              begin
                //получаем объект контакта
                GContact := JsonArray.Get(i) as TJSONObject;
                //получаем объект title
                GTitle := GContact.Get('title').JsonValue as TJSONObject;
                //читаем значение пары $t
                if Assigned(GTitle) then
                  Memo1.Lines.Add(GTitle.Get('$t').JsonValue.Value)
              end;
            end;
            break;
          end;
        end;
      finally
        Pairs.Free;
      end;
      JsonObject.Free;
    end;
  finally
    JsonStream.Free;
  end;
end;

Процедура расписана как можно более полно, вплоть до создания отдельных переменных под каждый объект. Поэтому, как говориться, комментарии излишни :). Остается только в который уже раз (наверное сотый) напомнить про строки, а именно, указать вот на эту строку в коде:

Memo1.Lines.Add(GTitle.Get('$t').JsonValue.Value)

И сказать, что значение Value довольно часто может быть в UTF-8, а в Google API так вообще всегда в UTF-8, поэтому при разработке под Windows, для преобразования строк следует использовать один из способов, предложенных, например, в статье «3 варианта работы с кодировками веб-страниц в Delphi.» и писать, например, так:

Memo1.Lines.Add(UTF8ToAnsi(GTitle.Get('$t').JsonValue.Value))

Вот, пожалуй, основная «тонкость» в этом коде. Теперь посмотрим аналогичный парсинг, но уже с использованием библиотеки SuperObject. Вот как выглядит процедура парсинга названий контактов GMail с использованием SuperObject:

procedure TForm3.Button2Click(Sender: TObject);
var
  JsonObject, GContact: ISuperObject;
  JsonStream: TStringStream;
  JsonArray: TSuperArray;
  i: integer;
begin
  JsonStream := TStringStream.Create;
  try
    //загружаем файл
    JsonStream.LoadFromFile(edFile.Text);
    //создаем объект
    JsonObject := SO(JsonStream.DataString);
    //получаем массив entry
    JsonArray := JsonObject.A['feed.entry'];
    if Assigned(JsonArray) then
      //читаем названия контактов из title
      for i := 0 to JsonArray.Length - 1 do
      begin
        GContact := JsonArray.O[i];
        Memo1.Lines.Add(Utf8ToAnsi(GContact.S['title.$t']));
      end;
  finally
    JsonStream.Free;
  end;
end;

Ощущаете разницу? :) Очевидным и неоспоримым преимуществом SuperObject является работа с путями. Как видите в коде выше мы всего одной строкой кода добрались до массива entry и потом также просто прочитали значение пары $t из объекта title. В результате код получился…более изящным что  ли? Но, как оказалось, и SuperObject не лишен некоторых недостатков.

Парсинг  JSON в Delphi под MacOS

С точки зрения написания кода, что под Windows, что под MacOS практически ничего не изменяется, разве, что не требуется преобразование строк из UTF-8. То есть всё та же «проблемная строка» кода вновь становится такой:

  Memo1.Lines.Add(GTitle.Get('$t').JsonValue.Value)

А вот по части использования библиотек для парсинга JSON под MacOS — тут пока SuperObject не применить. К сожалению, попытка собрать проект под Mac, содержащий SuperObject не увенчалась успехом. Виной тому, используемый в библиотеке модуль Windows.pas.

Вполне возможно, что  в будущем разработчики SuperObject доработают библиотеку и она станет полностью кроссплатформенной, но пока остается либо ждать, либо самим «допиливать» библиотеку, или — использовать уже готовую к работе под MacOS «родную» DBXJson — с ней программка под MacOS «взлетела» вообще без проблем.

Остается только добавить, что в настоящее время я пишу свою часть проекта с использованием как раз DBXJSON и не испытываю никакого особенного дискомфорта по этому поводу.  Да, после SuperObject было немного не привычно и неудобно «выковыривать» данные из JSON-объектов, но со временем привык и, теперь работа идёт без каких-либо проволочек и проблем. А SuperObject — это ИМХО самая удобная библиотека для парсинга JSON в Delphi. Жаль только, что пока не кроссплатформенная :)

Книжная полка

	Автор: Андрей Шкрыль Название: Разработка клиент-серверных приложений в Delphi Описание: Рассмотрены практические вопросы по разработке клиент-серверных приложений в среде Delphi 7 и Delphi 2005 с использованием СУБД MS SQL Server 2000, InterBase и Firebird. Приведена информация о теории построения реляционных баз данных и языке SQL. Освещены вопросы эксплуатации и администрирования СУБД.
	Автор: Антон Григорьев Название: О чем не пишут в книгах по Delphi Описание: Рассмотрены малоосвещенные вопросы программирования в Delphi. Описаны методы интеграции VCL и API. Показаны внутренние механизмы VCL и приведены примеры вмешательства в эти механизмы. Рассмотрено использование сокетов в Delphi: различные режимы их работы, особенности для протоколов TCP и UDP и др.