Книга о Synapse. Глава 2 «Работа с FTP в Synapse»

Прошло уже больше месяца с момента последней публикации в блоге. Так получилось, что все это время я к Delphi практически не обращался — занимался вещами далекими и от Delphi и от программирования, в принципе. По сему пропустил и выход AppMethod, но, думаю, что этот пробел я со временем восполню, а пока решил вернуться к работе над Synapse и предоставить на всеобщий обзор следующую главу, касающуюся работы с FTP в Synapse. По этому протоколу в блоге информации мало, поэтому большая часть главы писалась с нуля. PDF-версия главы — в конце сообщения.  Первая глава по сокетам в Synapse доступна здесь, вторая (по HTTP) — здесь.

Общие сведения о протоколе

FTP (англ. File Transfer Protocol — протокол передачи файлов) — стандартный протокол, предназначенный для передачи файлов по TCP-сетям (например, Интернет).

Протокол построен на архитектуре «клиент-сервер» и использует разные сетевые соединения для передачи команд и данных между клиентом и сервером. Пользователи FTP могут пройти аутентификацию, передавая логин и пароль открытым текстом, или же, если это разрешено на сервере, могут подключиться анонимно.

Можно использовать протокол SSH для безопасной передачи, скрывающей (шифрующей) логин и пароль, а также шифрующей содержимое.

FTP является одним из старейших прикладных протоколов, появившимся задолго до HTTP, и даже до TCP/IP, в 1971 году.

Особенность протокола FTP состоит в том, что он использует множественное  подключение. При этом один канал является управляющим, через который поступают команды серверу и возвращаются его ответы (обычно через TCP-порт 21), а через остальные происходит собственно передача данных, по одному каналу на каждую передачу.

Поэтому в рамках одной сессии по протоколу FTP можно передавать одновременно несколько файлов, причём в обоих направлениях. Для каждого канала данных открывается свой TCP порт, номер которого выбирается либо сервером, либо клиентом, в зависимости от режима передачи.

Передача данных может осуществляться в любом из трёх режимов:

1. Поточный режим — данные посылаются в виде непрерывного потока, освобождая FTP от выполнения какой бы то ни было обработки. Вместо этого, вся обработка выполняется TCP.
2. Блочный режим — FTP разбивает данные на несколько блоков (блок заголовка, количество байт, поле данных) и затем передаёт их TCP.
3. Режим сжатия — данные сжимаются единым алгоритмом.

При передаче данных по сети могут быть использованы четыре представления данных:

1. ASCII — используется для текста. Данные, если необходимо, до передачи конвертируются из символьного представления на хосте-отправителе в «восьмибитный ASCII», и (опять же, если необходимо) в символьное представление принимающего хоста. Как следствие, этот режим не подходит для файлов, содержащих не только обычный текст.
2. Режим изображения (бинарный) — устройство-отправитель посылает каждый файл байт за байтом, а получатель сохраняет поток байтов при получении. Поддержка данного режима была рекомендована для всех реализаций FTP.
3. EBCDIC — используется для передачи обычного текста между хостами в кодировке EBCDIC. В остальном, этот режим аналогичен ASCII-режиму.
4. Локальный режим — позволяет двум компьютерам с идентичными установками посылать данные в собственном формате без конвертации в ASCII.

FTP может работать в активном или пассивном режиме, от выбора которого зависит способ установки соединения.

В активном режиме клиент создаёт управляющее TCP-соединение с сервером и отправляет серверу свой IP-адрес и произвольный номер клиентского порта, после чего ждёт, пока сервер не запустит TCP-соединение с этим адресом и номером порта. В случае, если клиент находится за брандмауэром и не может принять входящее TCP-соединение, может быть использован пассивный режим.

В пассивном режиме клиент использует поток управления, чтобы послать серверу команду PASV, и затем получает от сервера его IP-адрес и номер порта, которые затем используются клиентом для открытия потока данных с произвольного клиентского порта к полученному адресу и порту.

Сервер отвечает по потоку управления трехзначными ASCII-кодами состояния с необязательным текстовым сообщением. Например, «200» (или «200 ОК») означает, что последняя команда была успешно выполнена. Цифры представляют код ответа, а текст — разъяснение или запрос. Текущая передача по потоку данных может быть прервана с помощью прерывающего сообщения, посылаемого по потоку управления.

Команды FTP

Список основных команд FTP представлен в таблице ниже

Коды ответов FTP

Ответ FTP сервера на любую команду FTP сервера состоит из трех цифр.
Первая цифра отвечает за один из трёх исходов: успех, отказ или указание на ошибку либо неполный ответ.
Вторая цифра определяет тип ошибки.
Третья цифра окончательно специфицирует ошибку.

Рассмотрим значение каждой цифры в каждой позиции.

В Synapse работа с протоколом FTP реализована в модуле FTPSend.pas. Рассмотрим этот модуль подробно и реализуем несколько примеров по работе с FTP в Synapse.

Модуль FTPSend.pas

Основным классом в модуле FTPSend.pas является TFPSend – класс, реализующий клиент для работы с FTP протоколом. Однако для упрощения работы с данными, поступающими от сервера, этот модуль содержит также и другие вспомогательные классы, которые мы и рассмотрим вначале.

Класс TFTPListRec

Объекты этого класса хранят информацию о файлах и поддиректориях, полученных с FTP-сервера.

У класса TFTPListRec определены следующие свойства:

property FileName: string

property Directory: Boolean

property Readable: Boolean

property FileSize: int64

property FileTime: TDateTime

property OriginalLine: string

property Mask: string

property Permission: string

Класс TFTPList

Объект этого класса содержит информацию обо всех объектах, находящихся в определенной директории на FTP-сервере.

У класса определены следующие свойства:

property List: TList

property Items[Index: Integer]: TFTPListRec

property Lines: TStringList

property Masks: TStringList

property UnparsedLines: TStringList

Также класс содержит методы:

procedure Clear; virtual;

function Count: integer; virtual;

procedure Assign(Value: TFTPList); virtual;

procedure ParseLines; virtual;

Класс TFTPSend

Как было сказано выше, класс TFTPSend реализует работу с протоколом FTP. Рассмотрим какие свойства, методы и события содержит этот класс.

Свойства класса:

property ResultCode: Integer

property ResultString: string

property FullResult: TStringList

property Account: string

property FWHost: string

property FWPort: string

property FWUsername: string

property FWPassword: string

property FWMode: integer

property Sock: TTCPBlockSocket

property DSock: TTCPBlockSocket

property DataStream: TMemoryStream

property DataIP: string

property DataPort: string

property DirectFile: Boolean

property DirectFileName: string

property CanResume: Boolean

property PassiveMode: Boolean

property ForceDefaultPort: Boolean

property ForceOldPort: Boolean

property FtpList: TFTPList

property BinaryMode: Boolean

property AutoTLS: Boolean

property FullSSL: Boolean

property IsTLS: Boolean

property IsDataTLS: Boolean

property TLSonData: Boolean

Методы класса

function ReadResult: Integer; virtual;

procedure ParseRemote(Value: string); virtual;

procedure ParseRemoteEPSV(Value: string); virtual;

function FTPCommand(const Value: string): integer; virtual;

function Login: Boolean; virtual;

function Logout: Boolean; virtual;

procedure Abort; virtual;

procedure TelnetAbort; virtual;

function List(Directory: string; NameList: Boolean): Boolean; virtual;

function RetrieveFile(const FileName: string; Restore: Boolean): Boolean; virtual;

function StoreFile(const FileName: string; Restore: Boolean): Boolean; virtual;

function StoreUniqueFile: Boolean; virtual;

function AppendFile(const FileName: string): Boolean; virtual;

function RenameFile(const OldName, NewName: string): Boolean; virtual;

function DeleteFile(const FileName: string): Boolean; virtual;

function FileSize(const FileName: string): int64; virtual;

function NoOp: Boolean; virtual;

function ChangeWorkingDir(const Directory: string): Boolean; virtual;

function ChangeToParentDir: Boolean; virtual;

function ChangeToRootDir: Boolean; virtual;

function DeleteDir(const Directory: string): Boolean; virtual;

function CreateDir(const Directory: string): Boolean; virtual;

function GetCurrentDir: String; virtual;

function DataRead(const DestStream: TStream): Boolean; virtual;

function DataWrite(const SourceStream: TStream): Boolean; virtual;

События класса

TFTPStatus = procedure(Sender: TObject; Response: Boolean;
const Value: string) of object;
property OnStatus: TFTPStatus

Вспомогательные методы

function FtpGetFile(const IP, Port, FileName, LocalFile,  User, Pass: string): Boolean;

Функция для получения файла с именем FileName с сервера и сохранения его на диске с именем LocalName.

function FtpPutFile(const IP, Port, FileName, LocalFile,  User, Pass: string): Boolean;

Функция для передачи файла LocalName с локального диска на сервер. Файл сохраняется на сервере с именем FileName.

function FtpInterServerTransfer(const FromIP, FromPort, FromFile, FromUser, FromPass: string; const ToIP, ToPort, ToFile, ToUser, ToPass: string): Boolean;

Функция для передачи файла с одного FTP сервера на другой.

Примеры работы с FTP в Synapse

Первый пример: подключение к серверу и работа с директориями

В качестве первого примера рассмотрим как правильно подключаться к FTP серверу и осуществлять навигацию по директориям.

Создаем новый проект (назовем его «syna_ftp») и размещаем на главной форме компоненты как показано на рисунке:

На форме расположены следующие компоненты:

• 3 TEdit для ввода адреса сервера, имени пользователя и пароля
• TButton для подключения к серверу или разрыва соединения
• TListView для вывода информации об объектах в текущей директории
• TMemo для вывода информации полученной/отправленной по каналу управления

Наша программа будет работать следующим образом:

1. Подключаться к серверу и считывать данные об объектах в текущей директории
2. Двойной клик по записи в ListView будет осуществлять переход в выбранную директорию или на один уровень вверх (для этого мы предусмотрим в ListView отдельный элемент.

Теперь подключаем в uses главного модуля приложения модуль FtpSend и пишем обработчики событий OnCreate и OnDestroy главной формы и OnStatus для объекта FTPSend:

unit uMain;
 
interface
 
uses
  ..., ftpsend, ....;
 
type
  TForm3 = class(TForm)
    ...
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    procedure Status(Sender: TObject; Response: Boolean; const Value: string);
  public
    FTPSend: TFTPSend;
  end;
 
var
  fmain: Tfmain;
 
implementation
 
{$R *.dfm}
 
procedure TForm3.FormCreate(Sender: TObject);
begin
  FTPSend:=TFTPSend.Create;
  FTPSend.OnStatus:=Status;
end;
 
procedure TForm3.FormDestroy(Sender: TObject);
begin
  FTPSend.Free;
end;
 
procedure Tfmain.Status(Sender: TObject; Response: Boolean;
  const Value: string);
begin
  if Response then
    memLog.Lines.Add('--> '+Value)
  else
    memLog.Lines.Add('<-- '+Value)
end;

Теперь напишем вспомогательную процедуру, которая будет формировать содержимое ListView по данным из свойства FtpList объекта FTPSend:

procedure Tfmain.UpdateFileList;
var LI: TlistItem;
    I: Integer;
begin
  lbCurrDir.Caption:=FTPSend.GetCurrentDir;
  ListView1.Items.BeginUpdate;
  try
   ListView1.Items.Clear;
    {создаем элемент для перехода на один уровень вверх}
    LI:=ListView1.Items.Add;
    LI.Caption:='[...]';
    {заполняем список информацией об объектах в текущей директории}
    for I := 0 to FTPSend.FtpList.Count-1 do
      begin
        LI:=ListView1.Items.Add;
        LI.Caption:=FTPSend.FtpList[i].FileName;
        if FTPSend.FtpList[i].Directory then
          Li.SubItems.Add('Папка')
        else
          Li.SubItems.Add('Файл');
        LI.SubItems.Add(IntToStr(FTPSend.FtpList[i].FileSize));
        LI.SubItems.Add((DateToStr(FTPSend.FtpList[i].FileTime)));
        Li.SubItems.Add(FTPSend.FtpList[i].Permission);
      end;
  finally
    ListView1.Items.EndUpdate;
  end;
end;

Теперь напишем обработчик события OnClick кнопки btnLogin:

procedure Tfmain.btnLoginClick(Sender: TObject);
const cLogin = 'Login';
      cLogout = 'Logout';
var i:integer;
begin
  if btnLogin.Caption=cLogin then
    begin
      //задаем параметры соединения
      FTPSend.TargetHost:=edServer.Text;
      FTPSend.UserName:=edUserName.Text;
      FTPSend.Password:=edPassword.Text;
      //используем пассивный режим
      FTPSend.PassiveMode:=True;
      //вход произведен успешно
      if FTPSend.Login then
        begin
         //выводим информацию о текущей директории
         lbCurrDir.Caption:=FTPSend.GetCurrentDir;
         //получаем информацию об объектах в директории
         FTPSend.List(lbCurrDir.Caption, false);
         //обновляем список
         UpdateFileList;
         //меняем надпись кнопки на "Logout"
         btnLogin.Caption:=cLogout
        end
      else
        memLog.Lines.Add('Error connect')
   end
  else
    begin
      //завершаем сессию
      FTPSend.Logout;
      //меняем надпись кнопки на "Login"
      btnLogin.Caption:=cLogin
    end;
end;

Остается написать обработчик двойного клика в ListView и проверить работу программы. Пишем обработчик:

procedure Tfmain.ListView1DblClick(Sender: TObject);
var b: boolean;
begin
  if not Assigned(ListView1.Selected) then Exit;
  //если пробуем подняться на уровень вверх
  if ListView1.ItemIndex=0 then
    b:=FTPSend.ChangeToParentDir
  else
    //пробуем сменить директорию на выбранную
    b:=FTPSend.ChangeWorkingDir(ListView1.Selected.Caption);
 if b then
   begin
     //смена текущей директории прошла успешно
     //получаем данные об объектах в текущей директории
     FTPSend.List(EmptyStr,False);
     //обновляем список
     UpdateFileList;
   end
 else
   memLog.Lines.Add('Change current directory filed')
end;

Теперь можно запустить приложение и проверить его работу:

По логу работы программы вы можете проследить всю цепочку «общения» клиента и сервера, а используя ListView перемещаться по директориям на сервере.

Второй пример: передача данных с заполнением ProgressBar’а

При изучении работы класса THTTPSend мы рассматривали пример скачивания больших файлов с заполнением ProgressBar’a. Рассмотрим и в этой главе подобный пример – научимся загружать/скачивать данные с заполнением ProgressBar.

В начале рассмотрим в чем будут заключаться особенности этого примера от рассмотренного ранее. Во-первых, если при скачивании файла по HTTP сервер может не вернуть нам размер скачиваемого файла, то при работе с FTP мы можем точно знать каков размер файла (при выполнении команды LIST мы получим всю информацию об объекте, включая и его размер). Во-вторых, следует учитывать особенность самого протокола FTP – многоканальную работу. Так, если обработчик OnStatus объекта FTPSend возвращает нам информацию исключительно из канала управления, то для отслеживания передачи информации по каналу данных нам необходимо написать обработчик OnStatus для сокета DSock (сокет канала данных).

Теперь приступим к работе над примером. В качестве основы для работы воспользуемся предыдущим примером. Копируем код предыдущего примера в другую директорию и добавляем на форму компонент TProgressBar как показано на рисунке ниже, а также компоненты:

• TPopupMenu для выбора операции с объектом в текущей директории.
• TOpenFileDialog – для выбора файла на локальном диске.

У компонента ListView в свойстве PopupMenu указываем компонент меню, а в самом меню создаем следующие элементы:

1. Скачать файл
2. Загрузить файл на сервер
3. Удалить

Теперь приступим к написанию кода программы. Чтобы использовать события сокета нам необходимо подключить в uses модуль blcksock. Теперь напишем обработчик события OnStatus для сокета:

procedure Tfmain.DSockStatus(Sender: TObject; Reason: THookSocketReason;
  const Value: String);
begin
  if Reason in [HR_ReadCount, HR_WriteCount] then
    ProgressBar1.Position:=ProgressBar1.Position+StrToInt(Value);
end;

Здесь мы проверяем какая операция в данный момент осуществляется и, если это операция чтения или записи, то увеличиваем свойство Position у ProgressBar.

Теперь напишем обработчик OnClick элемента меню «Скачать файл». Обработчик может выглядеть следующим образом:

procedure Tfmain.N1Click(Sender: TObject);
begin
  if not Assigned(ListView1.Selected) then Exit;
  if ListView1.Selected.Index=0 then Exit;
  //если выбрана папка, то выводим в лог сообщение
  if ListView1.Selected.SubItems[0]='Папка' then
    memLog.Lines.Add('Can''''t downoload directory')
  else
    //скачиваем файл
    begin
      //устанавливаем свойства ProgressBar
      ProgressBar1.Max:=StrToInt(ListView1.Selected.SubItems[1]);
      ProgressBar1.Position:=0;
      //определяем обработчик событие
      FTPSend.DSock.OnStatus:=DSockStatus;
      //пробуем скачать файл
      if FTPSend.RetrieveFile(ListView1.Selected.Caption,False) then
        begin
          //скачивание прошло успешно - сохраняем файл
          FTPSend.DataStream.SaveToFile(ListView1.Selected.Caption);
          //выводим сообщение об успешной закачке
          ShowMessage('Download complete');
        end
      else
        //загрузка не удалась - выводим сообщение в лог
        memLog.Lines.Add('Can''''t downoload file');
      ProgressBar1.Position:=0;
      FTPSend.DSock.OnStatus:=nil;
    end;
end;

Рассмотрим этот обработчик подробно.

Чтобы скачать файл мы вначале проверяем выбран ли какой-либо объект в списке ListView и, если ничего не выбрано, то выходим из обработчика.

if not Assigned(ListView1.Selected) then Exit;

Если в ListView выделен какой-либо элемент, то определяем является ли этот элемент самым первым в списке.

if ListView1.Selected.Index=0 then Exit;

Если это так, то значит пользователь выбрал служебный элемент […] для перехода на уровень вверх и, следовательно, т.к. скачать мы ничего в этом случае не можем, то работа прерывается.
Следующая проверка – проверка на тип объекта.

if ListView1.Selected.SubItems[0]='Папка' then
    memLog.Lines.Add('Can''''t downoload directory')

Если выбрана папка, то выводим сообщение в лог о том, что мы не можем скачать папку и выходим из обработчика.

Если в ListView выбран файл, то мы точно знаем его размер – он записан во втором столбце ListView, поэтому мы можем настроить наш ProgressBar, установив ему верное значение свойство Max, что мы и делаем.

//устанавливаем свойства ProgressBar
ProgressBar1.Max:=StrToInt(ListView1.Selected.SubItems[1]);

Далее мы назначаем обработчик события OnStatus сокета канала данных:

FTPSend.DSock.OnStatus:=DSockStatus;

И пробуем скачать файл и сохранить его на диске

if FTPSend.RetrieveFile(ListView1.Selected.Caption,False) then
  begin
   //скачивание прошло успешно - сохраняем файл
   FTPSend.DataStream.SaveToFile(ListView1.Selected.Caption);
   <i>//выводим сообщение об успешной закачке
   ShowMessage('Download complete');
  end
else
 //загрузка не удалась - выводим сообщение в лог
 memLog.Lines.Add('Can''''t downoload file');</i>

В любом случае, после выполнения операции скачивания файла убираем с сокета обработчик и обнуляем прогресс в ProgressBar:

ProgressBar1.Position:=0;
FTPSend.DSock.OnStatus:=nil;

Если не снять обработчик OnStatus с сокета, то при последующей работе с FTPSend ProgressBar будет пробовать заполняться, т.к. через канал данных проходят все данные, в т.ч. и данные о содержимом директории.

Обработчик события OnClick элемента меню «Загрузить файл на сервер» будет немногим отличаться от приведенного выше, поэтому просто приведем его код с комментариями:

procedure Tfmain.N4Click(Sender: TObject);
var b:boolean;
begin
  if OpenDialog1.Execute then
    begin
      //загружаем данные файла в поток
      FTPSend.DataStream.LoadFromFile(OpenDialog1.FileName);
      //устанавливаем значения свойств ProgressBar'a
      ProgressBar1.Position:=0;
      ProgressBar1.Max:=FTPSend.DataStream.Size;
      //определяем обработчик события
      FTPSend.DSock.OnStatus:=DSockStatus;
      //пробуем загрузить файл в директорию
      b:=FTPSend.StoreFile(ExtractFileName(OpenDialog1.FileName), False);
      //убираем обработчик события
      FTPSend.DSock.OnStatus:=nil;
      if b then
        begin
          //загрузка прошла успешно - обновляем список объектов
          FTPSend.List(EmptyStr,False);
          UpdateFileList;
        end;
      //обнуляем прогресс
      ProgressBar1.Position:=0;
    end;
end;

И третий обработчик – обработчик события OnClick элемента меню «Удалить»:

procedure Tfmain.N2Click(Sender: TObject);
var b:boolean;
begin
  if not Assigned(ListView1.Selected) then Exit;
  if ListView1.Selected.Index=0 then Exit;
  if ListView1.Selected.SubItems[0]='Папка' then
    b:=FTPSend.DeleteDir(ListView1.Selected.Caption)
  else
    b:=FTPSend.DeleteFile(ListView1.Selected.Caption);
  if b then
    begin
      memLog.Lines.Add('Delete object complete');
      //получаем данные об объектах в текущей директории
      FTPSend.List(EmptyStr,False);
      //обновляем список
      UpdateFileList;
    end
  else
    memLog.Lines.Add('Can''''t delete object');
end

Теперь можно запустить приложение, подключиться к серверу и проверить работу с файлами:

Третий пример: докачка файлов

Ещё одной немаловажной проблемой при работе с FTP является докачка файлов. На FTP сервере могут содержаться файлы самого разного размера и наличие возможности загрузить файл, начиная с определенной позиции после восстановления соединения с сервером, является скорее необходимостью для современных FTP-клиентов, а не «ещё одной дополнительной возможностью». И в этом примере мы разберемся с тем, как можно получать/отправлять данные с места определенной позиции  в файле или, иначе говоря, производить докачку файлов.

Как докачать файл по FTP?

Чтобы начать загрузку файла с определенной позиции FTP-клиент должен выполнить как минимум две команды:

1. REST – для указания серверу позиции с которой необходимо получать данные из файла.
2. RETR – для скачивания файла.

В Synapse обе эти команды реализованы в методах TFTPSend, которые мы уже использовали ранее – это RetrieveFile и StoreFile. Оба эти метода содержат такой входной параметр как Restore. Этот параметр указывает будет ли производится докачка файла с последней позиции в файле (параметр содержит True) или передача данных начнется с начала (параметр содержит False).

Так как не каждый FTP-сервер поддерживает докачку файлов, то для того, чтобы узнать поддерживается ли эта возможность на сервере, у TFTPSend имеется специальное свойство — CanResume, которое будет содержать значение True, если сервер поддерживает докачку.

Таким образом, чтобы реализовать докачку файлов по FTP нам не необходимо внести в предыдущий пример совсем незначительные изменения. Теперь приступим к реализации практического примера.

Реализуем FTP-клиент с возможностью докачки файлов

Копируем исходный код предыдущего примера в отдельную папку и переименовываем проект, например, в syna_ftp_resume.

Теперь нам необходимо немного изменить обработчики OnClick элементов меню «Скачать файл» и «Загрузить файл на сервер». Изменения в этих методах будут минимальными, а точнее – по одной строке в каждом методе:

для обработчика OnClick у элемента «Скачать файл» строку:

if FTPSend.RetrieveFile(ListView1.Selected.Caption,False) then

необходимо поменять следующим образом:

if FTPSend.RetrieveFile(ListView1.Selected.Caption, FTPSend.CanResume) then

и, соответственно, в обработчике OnClick элемента «Загрузить файл на сервер» строка:

b:=FTPSend.StoreFile(ExtractFileName(OpenDialog1.FileName), False);

меняется на:

b:=FTPSend.StoreFile(ExtractFileName(OpenDialog1.FileName), FTPSend.CanResume);

Теперь, если FTP-сервер поддерживает докачку файлов, то, в случае разрыва связи с сервером и последующего его восстановления, файл будет скачиваться/закачиваться с той позиции на которой произошел разрыв. Но на этом наш пример не заканчивается. Не стоит забывать про такой элемент интерфейса нашей программы как ProgressBar. Если Вы прямо сейчас попробуете реализовать, например, докачку файла, начиная с середины, то заметите, что после восстановления процесса загрузки ProgressBar заполниться ровно наполовину. Происходит это потому, что мы не указываем в свойстве ProgressBar.Position начальную позицию в файле с который мы начинаем загрузку. Чтобы ProgressBar заполнялся корректно, необходимо отследить момент, когда на сервер отправляется команда REST и выделить из строки команды значение позиции в файле.

Строка на выполнение команды REST может выглядеть, например, так:

REST 12567899

Соответственно, нам необходимо выделить из этой строки число 12567899 и указать его в свойстве ProgressBar.Position. Делать это удобно в обработчике события OnStatus для свойства FTPSend.Sock. Этот обработчик у нас уже есть в программе и нам его, опять же, достаточно дописать следующим образом:

procedure Tfmain.Status(Sender: TObject; Response: Boolean; const Value: string);
begin
if Response then
  memLog.Lines.Add('--> '+Value)
else
  memLog.Lines.Add('<-- '+Value); //на сервер отправляется команда REST if pos('REST', Value)>0 then
  ProgressBar1.Position:=StrToInt64Def(copy(value,Pos('REST',Value)+5,Length(Value)-Pos('REST',Value)-4),0)
end;

Теперь с реализацией докачки файлов все в порядке – если сервер поддерживает докачку, то после разрыва связи файл именно докачивает, а ProgressBar корректно реагирует на восстановление процесса скачивания/загрузки файлов.

Четвертый пример: выполнение произвольных команд

Бывают случаи, когда имеющихся методов и свойств класса Synapse оказывается недостаточно для выполнения реализации каких-либо функций в программе. Например, у класса TFTPSend отсутствует метод с помощью которого можно изменять атрибуты файлов на сервере. Для реализации такой возможности нам необходимо использовать метод FTPCommand и самостоятельно разбирать ответ сервера. Ниже рассмотрены два примера использования этой полезной функции в Synapse.

Копируем исходный код предыдущего примера в отдельную папку и переименовываем проект, например, в syna_ftp_commands.

Теперь на главную форму приложения добавляем компоненты, как показано на рисунке ниже:

• CommandBox: TComboBox – выпадающий список в который мы будем записывать все поддерживаемые команды
• edCmdParams: TEdit – текстовое поле в которое мы впоследствии будем записывать параметры команды
• btnCmd: TButton – кнопка «Выполнить» клик по которой будет выполнять произвольную команду

Теперь нам необходимо научиться получать список команд, поддерживаемых FTP-сервером. Для получения списка поддерживаемых команд достаточно отправить на сервер команду HELP без каких-либо дополнительных параметров. В результате FTP-сервер вернет в ответе следующий ответ (список команд в ответе может отличаться в зависимости от настроек сервера):
214-The following commands are recognized.
ABOR ACCT ALLO APPE CDUP CWD  DELE EPRT EPSV FEAT HELP LIST MDTM MKD
MODE NLST NOOP OPTS PASS PASV PORT PWD  QUIT REIN REST RETR RMD RNFR
RNTO SITE SIZE SMNT STAT STOR STOU STRU SYST TYPE USER XCUP XCWD XMKD
XPWD XRMD
214 Help OK.

Напишем отдельный метод, который будет отправлять на сервер команду HELP и заполнять список CommandBox. Назовем этот метод FTPHelp. Код методы будет следующий:

procedure Tfmain.FTPHelp;
begin
//если команда HELP успешно выполнена
if FTPSend.FTPCommand('HELP')=214 then
  begin
   //удаляем из полного текста ответа сервера первую и последнюю строку
    FTPSend.FullResult.Delete(0);
    FTPSend.FullResult.Delete(FTPSend.FullResult.Count-1);
    //очищаем ComboBox и записываем в него список доступных команд
    CommandBox.Clear;
    CommandBox.Items.DelimitedText:=FTPSend.FullResult.Text;
  end;
end;

Здесь мы, в случае положительного ответа сервера, удаляем из FullResult (полного ответа сервера) первую и последнюю строки, т.к. в них не содержаться названия команд, а затем оставшуюся строку передаем в CommandBox.

Вызывать этот метод мы будем сразу после того, как происходит авторизация на сервере, т.е. необходимо в обработчике OnClick кнопки btnLogin добавить следующую строку:

procedure Tfmain.btnLoginClick(Sender: TObject);
...
begin
if btnLogin.Caption=cLogin then
begin
....
if FTPSend.Login then
begin
...
//считываем список доступных команд
FTPHelp;
end
...
end;

Проверим работу программы. Запускаем приложение, авторизуемся на сервере и получаем следующий результат:

Теперь переходим к следующей части примера – попробуем выполнить какую-либо произвольную команду. Как было сказано выше, у TFTPSend нет метода с помощью которого можно было бы изменять атрибуты файла. Разберемся как можно выполнить это действие на примере ниже.

За выполнение специфичных для сервера команд, как раз таких как смена атрибутов файла или директории, отвечает команда SITE. Так, для того, чтобы изменить атрибуты файла с именем readme.html на значение 777 нам необходимо отправить на сервер  команду SITE со следующими аргументами:
SITE CHMOD 777 readme.html
и, в случае, если команды будет выполнена успешно, сервер вернет следующую строку ответа:
200 SITE CHMOD command ok.

Напишем обработчик OnClick кнопки «Выполнить» следующим образом:

procedure Tfmain.btnCmdClick(Sender: TObject);
begin
//если не выбрана команда - выходим
if CommandBox.ItemIndex0 then
  FTPSend.FTPCommand(CommandBox.Text+' '+edCmdParams.Text)
else
  FTPSend.FTPCommand(CommandBox.Text);
//выводим ответ сервера пользователю
ShowMessage(FTPSend.FullResult.Text);
end;

Теперь можно запустить приложение и попробовать выполнить, например, команду SITE. Результат представлен на рисунке:

Аналогичным образом можно выполнять и другие FTP-команды. При этом следует отметить, что для получения результата выполнения команды, наравне со свойством TFTPSend FullResult можно также использовать свойства ResultCode и ResultString.

Книжная полка

	Автор: Андрей Шкрыль Название: Разработка клиент-серверных приложений в Delphi Описание: Рассмотрены практические вопросы по разработке клиент-серверных приложений в среде Delphi 7 и Delphi 2005 с использованием СУБД MS SQL Server 2000, InterBase и Firebird. Приведена информация о теории построения реляционных баз данных и языке SQL. Освещены вопросы эксплуатации и администрирования СУБД.
	Автор: Антон Григорьев Название: О чем не пишут в книгах по Delphi Описание: Рассмотрены малоосвещенные вопросы программирования в Delphi. Описаны методы интеграции VCL и API. Показаны внутренние механизмы VCL и приведены примеры вмешательства в эти механизмы. Рассмотрено использование сокетов в Delphi: различные режимы их работы, особенности для протоколов TCP и UDP и др.