REST Client Library: использование API ВКонтакте.

Итак, как и говорил ранее, сегодня я решил вытащить из черновиков блога и немного доработать статью, посвященную работе с API социальной Сети «ВКонтакте«. В принципе, REST Client Library, о которой я уже рассказывал не раз, вполне сгодится для работы с любой социальной сетью или онлайн сервисом, которые предоставляют нам в распоряжение API. Но «ВКонтакте», всё же из всех мне известных социальных сетей (за исключением, наверное, Twitter) является самой популярной в России, поэтому с ней и попробуем поработать, используя в работе Delphi XE6. Ну, а чтобы было ещё более занимательно, попробуем написать небольшое приложение для Android. Кому потребуется приложение для Windows и VCL, думаю легко разберется в том, какие модули следует подключить  в uses, а какие наоборот — убрать.

1. Создаем свое приложение «ВКонтакте» и пробуем авторизовать пользователя.

Для начала работы с API «ВКонтакте» необходимо создать новое приложение и получить необходимые данные для авторизации пользователей. Для этого заходим на страницу разработчиков и жмем вверху страницы кнопку «Создать приложение«:

Далее придумываем нашему приложению название и задаем тип приложения — «Standalone-приложение«:

Жмем кнопку «Подключить приложение» после чего вам предложат подтвердить свое действие, выслав на мобильный телефон проверочный код. После подтверждения Вам станет доступно изменение настроек приложения:

Переходим на вкладку «Настройки» и запоминаем ID приложения и Защищенный ключ:

Теперь можно переходить к Delphi XE6 и попробовать реализовать авторизацию пользователя.

Запускаем Delphi XE6, создаем новый проект для мобильных устройств и на главную форму бросаем компоненты, покзанные на рисунке ниже:

Сейчас нам нужны будут следующие компоненты: TButton, TRESTClient, TRESTRequest, TRESTResponse и TOAuth2Authenticator. Клик по кнопке TButton будет вызывать процесс авторизации пользователя. Для начала, напишем процедуру авторизации пользователя.

Все необходимые данные для авторизации я определил как константы:

const
  cAppID = '427ххххх';
  cAppKey = '94ххххххххххххххххххххххp';
  cEndPoint = 'https://oauth.vk.com/authorize';

Теперь необходимо вызвать форму для авторизации пользователя «ВКонтакте» и получить Access Token. Как это делать я достаточно подробно рассказывал в самоё первой статье по REST Client Library. Подключаем в uses модуль REST.Authenticator.OAuth.WebForm.FMX и определяем следующую переменную:

type
  TForm1 = class(TForm)
    [...]
  private
    WebForm: Tfrm_OAuthWebForm;
  public
    { Public declarations }
  end;

Напомню, что Tfrm_OAuthWebForm — это форма, на которой расположен компонент TWebBrowser с помощью которого пользователь заходит на сайт, чтобы ввести свои логин/пароль и получить доступ для приложения к каким-либо данным своего аккаунта. Соответственно нам, как разработчикам, эта форма необходима, как минимум, для того, чтобы «отловить» редирект на специальный URL, который будет содержать необходимый нам Access Token. Для управления редиректами у Tfrm_OAuthWebForm определено сразу два события:

type
  TOAuth2WebFormRedirectEvent = procedure(const AURL: string; var DoCloseWebView : boolean) of object;
 
  property OnBeforeRedirect: TOAuth2WebFormRedirectEvent read FOnBeforeRedirect write FOnBeforeRedirect;
  property OnAfterRedirect: TOAuth2WebFormRedirectEvent read FOnAfterRedirect write FOnAfterRedirect;

Нам необходим обработчик события OnAfterRedirect. Напишем его:

type
  TForm1 = class(TForm)
   [...]
  private
    WebForm: Tfrm_OAuthWebForm;
    procedure AfterRedirect(const AURL: string; var DoCloseWebView : boolean);
    [...]
  public
    { Public declarations }
  end;
 
procedure TForm1.AfterRedirect(const AURL: string; var DoCloseWebView: boolean);
var i:integer;
    Str: string;
    Params: TStringList;
begin
  i:=pos('#access_token=',AURL);
  if (i>0) and (OAuth2Authenticator1.AccessToken=EmptyStr) then
    begin
      Str:=AURL;
      Delete(Str,1,i);
      Params:=TStringList.Create;
      try
        Params.Delimiter:='&';
        Params.DelimitedText:=Str;
        OAuth2Authenticator1.AccessToken:=Params.Values['access_token'];
        OAuth2Authenticator1.AccessTokenExpiry:=IncSecond(Now,StrToInt(Params.Values['expires_in']));
      finally
        Params.Free;
      end;
      WebForm.Close;
    end;
end;

Таким образом, после редиректа мы проверяем есть ли в URL подстрока #access_token= и, если такая строка имеется, то вытаскиваем из URL данные по Access Token и время его жизни — значение параметра expires_in.

Теперь нам необходимо создать форму, определить обработчик OnAfterRedirect и в нужный момент показать эту форму пользователю.
Что касается создания/уничтожения объекта формы, то это можно сделать где вам удобно. Для примера, я создаю форму авторизации в OnCreate главной формы, а уничтожаю, соответственно, в OnDestroy:

procedure TForm1.FormCreate(Sender: TObject);
begin
  WebForm:=Tfrm_OAuthWebForm.Create(nil);
  WebForm.OnAfterRedirect:=AfterRedirect;
end;
 
procedure TForm1.FormDestroy(Sender: TObject);
begin
  WebForm.Free;
end;

Процедуру авторизации пользователя напишем следующим образом:

type
  TForm1 = class(TForm)
    [...]
  private
    WebForm: Tfrm_OAuthWebForm;
    procedure AfterRedirect(const AURL: string; var DoCloseWebView : boolean);
    procedure Auth;
  public
    { Public declarations }
  end;
 
procedure TForm1.Auth;
begin
  OAuth2Authenticator1.AccessToken:=EmptyStr;
  OAuth2Authenticator1.ClientID:=cAppID;
  OAuth2Authenticator1.ClientSecret:=cAppKey;
  OAuth2Authenticator1.ResponseType:=TOAuth2ResponseType.rtTOKEN;
  OAuth2Authenticator1.AuthorizationEndpoint:=cEndPoint;
  WebForm.ShowWithURL(OAuth2Authenticator1.AuthorizationRequestURI);
end;

Здесь мы, опять же, используем компонент TOAuth2Authenticator — записываем в него данные нашего приложения (ID и секретный ключ), а также получаем URL, по которому необходимо перейти пользователю для авторизации.

Здесь стоит особое внимание обратить на следующую строку:

OAuth2Authenticator1.ResponseType:=TOAuth2ResponseType.rtTOKEN;

Здесь мы указываем какой тип ответа от сервера нам требуется и, в соответствии с этим параметром компонент будет формировать результат функции AuthorizationRequestURI. Если поле ResponseType оставить со значением по умолчанию (TOAuth2ResponseType.rtCode), то наш обработчик OnAfterRedirect окажется бесполезным, а вместо ключа доступа к API мы всегда будем получать на экране сообщение от VK вида:

Теперь вызываем метод Auth в обработчике OnClick кнопки и можем проверить наше приложение на каком-нибудь Android-устройстве:

procedure TForm1.Button1Click(Sender: TObject);
begin
  Auth;
end;

Вот так будет выглядеть окно авторизации пользователя в запущенном приложении:

Сразу после авторизации окно закроется и можно будет использовать API «ВКонтакте», что называется, на полную катушку.

2. Использование API «ВКонтакте»

Конечно, сегодня мы весь API «ВКонтакте» не переберем. Да и цели такой у меня не стоит. А вот некоторые моменты по работе с методами API рассмотрим.

С тем, как вызывать методы API вы можете ознакомиться на странице: http://vk.com/dev/api_requests.

Список всех доступных методов предоставлен на странице: http://vk.com/dev/methods

Вначале попробуем использовать какой-нибудь простенький метод. Например, в API есть довольно интересный метод — setOffline, который помечает текущего пользователя как offline. Метод доступен только приложениям с типом Standalone. Для вызова этого и других методов API и получения ответов сервера у нас на имеются следующие компоненты:

• RESTClient1: TRESTClient;
• RESTRequest1: TRESTRequest;
• RESTResponse1: TRESTResponse;

Чтобы выполнять запросы к API определим у компонента RESTClient1 свойство BaseURL — для «ВКонтакте» это свойство должно содержать следующий URL — https://api.vk.com/method. 

У компонента RESTRequest1 необходимо выставить следующие значения свойств:

• Client = RESTClient1
• Response  = RESTResponse1

Теперь попробуем вызвать метод  account.setOffline API ВКонтакте и вывести результат в ListBox. Добавим на форму приложения ещё одну кнопку и напишем для неё такой обработчик OnClick:

procedure TForm1.Button2Click(Sender: TObject);
begin
  RESTRequest1.Resource:='account.setOffline';
  RESTRequest1.Method:=TRESTRequestMethod.rmGET;
  RESTRequest1.Execute;
  ListBox1.Items.Add(RESTResponse1.Content)
end;

Теперь можно запустить приложение и проверить ответ сервера при вызове метода setOffline:

Соответствующим образом можно вызывать и другие методы API. Если же нам необходимо разобрать ответ сервера, то для этого можно воспользоваться свойством JSONValue компонента TRESTResponse.

Книжная полка

	Автор: Дмитрий Осипов Название: Delphi. Профессиональное программирование Описание: Книга рассчитана на подготовленного пользователя ПК, желающего самостоятельно научиться программировать и разрабатывать приложения и базы данных в среде Delphi. Опытные программисты смогут использовать издание как справочник. В тексте подробно описаны более 80 компонентов VCL, функции Object Pascal и Win32 API.
	Автор: Юрий Магда Название: Разработка приложений Microsoft Office 2007 в Delphi Описание: Описаны общие подходы к программированию приложений MS Office. Даны программные методы реализации функций MS Excel, MS Word, MS Access и MS Outlook в среде Delphi.